מדידת זרם, מתח והספק

מדידת מתח ישר גבוה מתחום הממיר (High DC Voltage)

הממיר התקבילי-ספרתי בכרטיס Uno מקבל מתח מ-0 עד V_ref = 5 V בלבד. אבל המתחים שאנו רוצים לנטר גבוהים יותר: סוללה של 12 V, לוח סולרי, ספק כוח מעבדתי. הפתרון הוא מחלק מתח משני נגדים: הוא מקטין את המתח ביחס קבוע לפני ההדק, ובסקיצה נכפיל את הקריאה באותו יחס.

הסקיצה עוברת שני שלבים: היא ממירה את הערך הגולמי N למתח על ההדק, כמו בכל מבוא תקבילי, ואחר כך כופלת את המתח במקדם החלוקה ומקבלת את המתח שלפני המחלק:

נשתמש בערכים של מודול "חיישן המתח" הנפוץ לתחום 0–25 V: R₁ = 30 kΩ ו-R₂ = 7.5 kΩ, ונוודא אותם בדוגמה שאחרי הסקיצה. בסרטוט הוספנו להגנה דיודת זנר וקבל. אם מחברים בטעות מתח גבוה מ-25 V, הזנר אינו מניח למתח ההדק לעלות הרבה מעל 5 V, והנגד הגדול R₁ מגביל את הזרם בו. הקבל מחליש את הרעש, והקריאה יציבה יותר.

// DC voltmeter 0-25 V: divider 30k / 7.5k into A0
const int   PIN_V = A0;
const float R1    = 30000.0;
const float R2    = 7500.0;
const float VREF  = 5.0;

void setup() {
  Serial.begin(9600);
}

void loop() {
  long sum = 0;
  for (int i = 0; i < 16; i++) sum += analogRead(PIN_V);
  float n    = sum / 16.0;                 // averaged raw value
  float vPin = n * VREF / 1023.0;          // voltage on A0
  float vIn  = vPin * (R1 + R2) / R2;      // voltage before the divider
  Serial.print("N = ");        Serial.print(n, 1);
  Serial.print("  Vpin = ");   Serial.print(vPin, 3);
  Serial.print(" V  Vin = ");  Serial.print(vIn, 2);
  Serial.println(" V");
  delay(1000);
}

N = 204.0  Vpin = 0.997 V  Vin = 4.99 V
N = 491.0  Vpin = 2.400 V  Vin = 12.00 V
N = 757.0  Vpin = 3.700 V  Vin = 18.50 V
N = 982.0  Vpin = 4.800 V  Vin = 24.00 V

העלינו בהדרגה את המתח של ספק כוח מעבדתי ל-5 V, 12 V, 18.5 V, 24 V. הקריאה מעט נמוכה מן המתח האמיתי, כי הממיר לוקח רק את החלק השלם.

חיישן זרם ACS712 מבוסס אפקט הול (Hall-Effect Current Sensor)

בשבב ACS712 הזרם הנמדד זורם במסלול נחושת בתוך המארז, בין ההדקים IP+ ו-IP−. הזרם יוצר סביב המסלול שדה מגנטי, ורכיב הול הסמוך אליו ממיר את השדה למתח; מגבר פנימי מגביר את המתח הזה ומוביל אותו להדק המוצא OUT. בין מסלול הנחושת למעגל המוצא יש בידוד גלווני: אין ביניהם שום חיבור חשמלי, ולכן מעגל העומס אינו צריך אדמה משותפת עם הבקר. לחיישן זרם זה מוצא תקבילי, והוא מודד את הזרם בשני הכיוונים.

ההזנה 5 V, והמוצא בזרם אפס שווה למחצית ההזנה, V_CC2 = 2.5 V. הרגישות היא השינוי במוצא לכל אמפר: בדגם 5 A המוצא עולה ב-185 mV בכל אמפר. הרגישות ומתח האפס הם ערכים טיפוסיים לפי דף הנתונים. זרם בכיוון החיובי (מ-IP+ אל IP−) מעלה את המוצא מעל 2.5 V, וזרם בכיוון ההפוך מוריד אותו מתחת לערך זה. בדגם 5 A המוצא נע בין 1.575 V ל-3.425 V.

בכרטיס Uno יחידה אחת של הערך הגולמי שווה לכ-4.9 mV, ובדגם 5 A זה כ-26 mA. לכן הסקיצה מחשבת ממוצע של כמה קריאות. ומתח האפס אינו בדיוק 2.5 V: הוא שונה מעט מיחידה ליחידה. הפתרון הפשוט: הסקיצה קוראת את המוצא עם הפעלת המערכת, כשהעומס מנותק, ושומרת אותו כמתח האפס V₀.

// ACS712-05B: zero read at start-up, current in amps
const int   PIN_I = A0;
const float SENS  = 0.185;          // V per A (typical, 5 A part)
const float VPC   = 5.0 / 1023.0;   // volts per count

float zeroV = 0;                    // output at zero current

float readVolts() {
  long s = 0;
  for (int i = 0; i < 64; i++) s += analogRead(PIN_I);
  return s / 64.0 * VPC;
}

void setup() {
  Serial.begin(9600);
  zeroV = readVolts();              // load must be OFF here
  Serial.print("zero = "); Serial.print(zeroV, 3); Serial.println(" V");
}

void loop() {
  float v = readVolts();
  float amps = (v - zeroV) / SENS;
  Serial.print("Vout = "); Serial.print(v, 3);
  Serial.print(" V  I = "); Serial.print(amps, 2); Serial.println(" A");
  delay(500);
}

zero = 2.468 V
Vout = 2.468 V  I = 0.00 A
Vout = 2.688 V  I = 1.19 A
Vout = 2.913 V  I = 2.40 A
Vout = 2.243 V  I = -1.22 A

מתח האפס של יחידה זו הוא 2.47 V (ולא 2.5 V), והזרם בעומס קיבל את הערכים 0 A, 1.2 A, 2.4 A, −1.2 A. הערך האחרון שלילי, כי הפכנו את כיוון הזרם בעומס.

שיטות אחרות למדידת זרם:

מלבד ACS712 יש עוד שתי שיטות נפוצות: נגד מדידה (שנט), נגד קטן מאוד המחובר בטור עם העומס, ושנאי זרם מתפצל, שליבתו נפתחת כמו צבת ונסגרת סביב מוליך. לא נלמד אותן לעומק בספר הזה; הטבלה מסכמת מתי משתמשים בכל שיטה.

חישוב הספק לעומס זרם ישר (DC Power)

כשהבקר מודד את המתח על העומס (סעיף 9.1) ואת הזרם בו (סעיף 9.2), הוא מחשב את ההספק בפעולת כפל אחת. כך הוא יודע, למשל, כמה הספק צורך מנוע, ומבחין מתי העומס פועל בהספק גבוה מן הרגיל.

סיכום נוסחאות הפרק:

מילון מונחים:

שאלות לתרגול: