מפעילים תעשייתיים

המגען (Contactor)

• סליל המגען, והדקיו A1–A2: המתח שלו רשום עליו, והערכים הנפוצים בלוחות הם 24 V (חילופין או ישר) ו-230 V חילופין. סליל של 230 V אינו מושך ב-24 V, וסליל של 24 V נשרף ב-230 V.
• מגעים ראשיים: שלושה מגעים פתוחים במנוחה, שמחברים את שלושת המופעים אל העומס במעגל הכוח.
• מגעי עזר: מגעים קטנים למעגל הפיקוד — להחזקה עצמית, לנעילה הדדית ולחיווי.

היצרן רושם את זרם המגען לפי קטגוריית שימוש: קטגוריה AC-1 לעומס התנגדותי כמו גוף חימום, וקטגוריה AC-3 למנוע השראתי. בהתנעה המנוע מושך זרם גדול פי כמה מהזרם הנומינלי שלו, ולכן הזרם המותר לאותו מגען ב-AC-3 קטן מאשר ב-AC-1. הזרם של עומס התנגדותי: I = PU.

מעגל החזקה עצמית (Self-Holding Circuit)

הפעלת מגען מבקר: ממסר ביניים (Interposing Relay)

את סליל המגען לעולם אין מחברים ישירות להדק הבקר: המתח שלו 24 V או 230 V, ומוצא ה-Uno הוא 5 V; הזרם שלו גדול בהרבה מ-20 mA; בניתוק שלו נוצר קוץ מתח; וחוטי הלוח ארוכים ועוברים לצד חוטי הכוח.

התוכנית בונה מחדש את ההחזקה העצמית בתוכנה: המשתנה run שומר את מצב המגען, ולהפסקה ולניתוק התרמי יש קדימות. לחצן ההפסקה סגור במנוחה, ולכן נקרא HIGH כשלוחצים עליו או כשהחוט שלו נקרע.

const int START = 2;   // S1, NO to GND
const int STOP  = 3;   // S0, NC to GND (open = stop)
const int OL    = 4;   // O.L aux contact 97-98, closes on trip
const int RELAY = 7;   // relay module IN -> K1 -> coil C1
bool run = false;

void setup() {
  pinMode(START, INPUT_PULLUP); pinMode(STOP, INPUT_PULLUP);
  pinMode(OL, INPUT_PULLUP);
  pinMode(RELAY, OUTPUT); digitalWrite(RELAY, LOW);
  Serial.begin(9600); Serial.println("READY");
}

void loop() {
  bool stopCmd = digitalRead(STOP) == HIGH;   // pressed or broken wire
  bool tripped = digitalRead(OL) == LOW;
  bool next = run;
  if (stopCmd || tripped) next = false;       // stop has priority
  else if (digitalRead(START) == LOW) next = true;
  if (next == run) return;                    // print only on change
  run = next;
  digitalWrite(RELAY, run ? HIGH : LOW);
  Serial.print("t = "); Serial.print(millis() / 1000.0, 1);
  Serial.print(" s  C1 "); Serial.print(run ? "ON" : "OFF");
  Serial.println(tripped ? "  O.L TRIP" : "");
}

READY
t = 2.0 s  C1 ON
t = 12.5 s  C1 OFF
t = 20.0 s  C1 ON
t = 95.3 s  C1 OFF  O.L TRIP
t = 185.0 s  C1 ON

בשנייה 95.3 ניתק הממסר התרמי; הלחיצה על S1 בשנייה 97 לא שינתה דבר, ואחרי איפוס הממסר התרמי אפשר היה שוב להפעיל. שימו לב: מודולי ממסר רבים פועלים ברמה נמוכה (אות LOW ב-IN מפעיל אותם), ואיתם התוכנית פועלת הפוך; נבדוק את המודול לפני החיבור.

נעילה הדדית בין מגענים (Interlocking)

כדי להפוך את כיוון הסיבוב של מנוע תלת-מופעי מחליפים בין שני מופעים בעזרת שני מגענים: C1 לסיבוב קדימה ו-C2 לסיבוב אחורה. אילו נסגרו שניהם יחד, היה נוצר קצר בין שני מופעים.

שסתומים חשמליים וברזים חשמליים (Solenoid and Motorized Valves)

סליל של שסתום במתח ישר מושך זרם קבוע I = UR, ומפעילים אותו בטרנזיסטור עם דיודת חופש כמו בפרק 10. בסליל במתח חילופין: כל עוד הליבה הנעה רחוקה, ההשראות של הסליל קטנה, ולכן הספק המשיכה גדול בהרבה מהספק ההחזקה אחרי שהליבה נסגרה. אם הליבה נתקעת, הזרם נשאר גדול והסליל נשרף.

הבקר נותן פקודת "פתח" ומחכה למפסק הגבול "פתוח". אם האות לא הגיע תוך זמן המהלך ועוד מרווח, הברז תקוע: מפסיקים את הפקודה ונותנים התרעה. זה אותו רעיון של פסק זמן שנשתמש בו בסוף הפרק.

מעגל כוח ומעגל פיקוד: תרשים חד-קווי (Single-Line Diagram)

גוף חימום הוא עומס התנגדותי: הזרם שלו I = PU מהרגע הראשון (קטגוריה AC-1). משאבה מונעת בידי מנוע השראתי: זרם ההתנעה גדול פי כמה מהנומינלי (קטגוריה AC-3), ומגינים עליה בממסר תרמי המכוון לזרם הנומינלי שרשום על לוחית המנוע. משאבה שפועלת בלי מים ("ריצה יבשה") מתחממת ונהרסת, ולכן מגינים עליה מפני ריצה יבשה.

יישום: מילוי מיכל במשאבה (Tank Filling)

משאבה ממלאת מיכל, והמים נצרכים מתחתיתו. במיכל שני מצופים: LOW בגובה h_L ו-HIGH בגובה h_H; כל מצוף סוגר את המגע שלו כשהמים מגיעים אליו ("רטוב"). המשאבה פועלת כש-LOW מתייבש, ונעצרת כש-HIGH נרטב. נכתוב את ההיגיון כמכונת מצבים: בכל רגע המערכת נמצאת במצב אחד, ונסרטט אותה בתרשים מצבים.

• WAIT: המשאבה מופסקת; אם LOW מתייבש, עוברים ל-FILL.
• FILL: המשאבה פועלת; אם HIGH נרטב, חוזרים ל-WAIT. אם LOW נשאר יבש יותר מפסק הזמן DRY_MS, המים אינם מגיעים (המקור ריק או הצינור קרוע) והמשאבה רצה יבשה: עוברים ל-FAULT.
• FAULT: המשאבה מופסקת וההתרעה פועלת עד ללחיצה על לחצן האיפוס. עוברים למצב זה גם אם HIGH רטוב ו-LOW יבש בו-זמנית: זה בלתי אפשרי פיזיקלית, ופירושו תקלה במצוף.

את פסק הזמן DRY_MS בוחרים לפי מדידה: מפעילים את המערכת ממיכל ריק ומודדים כמה זמן עובר עד שהמצוף LOW נרטב, ולוקחים בערך פי שניים מהזמן הזה. בדוגמה שלנו פסק הזמן הוא 300 s (5 min). פסק זמן קצר מדי נותן התרעת שווא כשמתחילים ממיכל ריק, ופסק זמן ארוך מדי משאיר את המשאבה לעבוד יבשה זמן רב.

הפונקציה go() מעבירה את המערכת למצב חדש: שומרת אותו, רושמת את זמן הכניסה בעזרת millis(), קובעת את שני המוצאים ומדפיסה את הסיבה. פסק הזמן בלי delay(): בכל מחזור נחשב את dt, הזמן שחלף במצב, ונשווה אותו לפסק הזמן.

const int LOW_SW = 2, HIGH_SW = 3;   // floats: closed (LOW) when wet
const int RST_BTN = 4;               // reset button to GND
const int PUMP = 7, ALARM = 8;       // relay module (K1 -> C1), alarm LED
const unsigned long DRY_MS = 300000UL;   // dry-run timeout
enum State { WAIT, FILL, FAULT };
State state;
unsigned long tStart;

void go(State s, const char *why) {  // enter a new state
  state = s;  tStart = millis();
  digitalWrite(PUMP, s == FILL);  digitalWrite(ALARM, s == FAULT);
  Serial.print("t = "); Serial.print(tStart / 1000);
  Serial.print(" s  "); Serial.println(why);
}

void setup() {
  pinMode(LOW_SW, INPUT_PULLUP); pinMode(HIGH_SW, INPUT_PULLUP);
  pinMode(RST_BTN, INPUT_PULLUP); pinMode(PUMP, OUTPUT); pinMode(ALARM, OUTPUT);
  Serial.begin(9600);
  go(WAIT, "START");
}

void loop() {
  bool wetL = digitalRead(LOW_SW) == LOW, wetH = digitalRead(HIGH_SW) == LOW;
  unsigned long dt = millis() - tStart;          // time in this state
  if (state != FAULT && wetH && !wetL) go(FAULT, "FLOAT ERROR");
  switch (state) {
    case WAIT:  if (!wetL) go(FILL, "LOW -> PUMP ON"); break;
    case FILL:  if (wetH) go(WAIT, "HIGH -> PUMP OFF");
                else if (!wetL && dt > DRY_MS) go(FAULT, "DRY RUN");
                break;
    case FAULT: if (digitalRead(RST_BTN) == LOW) go(WAIT, "RESET"); break;
  }
}

t = 0 s  START
t = 0 s  LOW -> PUMP ON
t = 733 s  HIGH -> PUMP OFF
t = 2733 s  LOW -> PUMP ON
t = 3033 s  DRY RUN
t = 3600 s  RESET
t = 3600 s  LOW -> PUMP ON
t = 4400 s  HIGH -> PUMP OFF

חישבנו את הצג מתוך מודל המיכל שבדוגמה (המים מתחילים ב-0.1 m). בשנייה 1800 המקור התייבש, ולכן כשהמשאבה חזרה לפעול היא רצה בלי מים, ואחרי 300 s המערכת עברה ל-FAULT; בשנייה 3600 המים חזרו ומפעיל המערכת לחץ על לחצן האיפוס.

סיכום נוסחאות הפרק:

מילון מונחים:

שאלות לתרגול: