المسافة والحضور والحركة

חיישן מרחק על-קולי – الحسّاس فوق الصوتي HC-SR04 (Ultrasonic Distance Sensor)

من أين يأتي العدد 58؟ الحسّاس يعطينا الزمن بالميكروثانية، ونريد المسافة بالسنتيمتر. نكتب السرعة بهذه الوحدات، 343 m/s = 0.0343 cm/µs ، ونعوّض في القانون:

أي أن الصوت يحتاج نحو 58 µs ليذهب سنتيمترا واحدا ويعود.

الوحدة HC-SR04: الأطراف وطريقة العمل – המודול HC-SR04: הדקים ואופן הפעולה:

const int TRIG = 9;
const int ECHO = 10;
const float V = 0.0343;                  // speed of sound: 343 m/s = 0.0343 cm/us

void setup() {
  Serial.begin(9600);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
}

void loop() {
  digitalWrite(TRIG, HIGH);                // 10 us trigger pulse
  delayMicroseconds(10);
  digitalWrite(TRIG, LOW);
  unsigned long t = pulseIn(ECHO, HIGH, 30000UL);   // 0 = timeout
  Serial.print("t = "); Serial.print(t);
  if (t == 0) {
    Serial.println(" us  no echo");
  } else {
    Serial.print(" us  d = "); Serial.print(V * t / 2, 1);
    Serial.println(" cm");
  }
  delay(100);
}

t = 583 us  d = 10.0 cm
t = 2915 us  d = 50.0 cm
t = 5831 us  d = 100.0 cm
t = 11662 us  d = 200.0 cm
t = 0 us  no echo

القراءة النموذجية لأجسام على بعد 10، 50، 100، 200 سنتيمترا، والسطر الأخير بلا جسم: لم يعد صدى فأعاد pulseIn القيمة 0.

מערכת עזר לחניה – مثال تطبيقي: نظام مساعدة الركن (Parking Assist)

الحسّاس فوق الصوتي يقيس المسافة إلى الحائط، والطنّان (זמזם) يصفّر أسرع كلما اقتربت السيارة. نقسم المسافة إلى أربع مناطق، ونضيف طنّانا سلبيا بين D8 والأرضي. الأمر tone(BUZZ, 2000, 60) يُخرج موجة مربّعة بتردد 2000 Hz مدّة 60 ms ثم يتوقف وحده. بدل delay طويل بين الصفّارات نقارن millis() بوقت الصفّارة السابقة، فيبقى القياس سريعا.

const int TRIG = 9, ECHO = 10, BUZZ = 8;   // BUZZ: passive buzzer
const unsigned int GAP[] = {0, 500, 200, 0};   // ms between beeps
unsigned long lastBeep = 0;

void setup() {
  Serial.begin(9600);
  pinMode(TRIG, OUTPUT);
  pinMode(ECHO, INPUT);
}

void loop() {
  digitalWrite(TRIG, HIGH); delayMicroseconds(10); digitalWrite(TRIG, LOW);
  unsigned long t = pulseIn(ECHO, HIGH, 30000UL);
  float d = (t == 0) ? 999.0 : t / 58.0;   // no echo = far away
  int z = (d > 100) ? 0 : (d > 50) ? 1 : (d > 25) ? 2 : 3;
  if (z == 0) noTone(BUZZ);
  else if (z == 3) tone(BUZZ, 2000);       // stop: continuous tone
  else if (millis() - lastBeep >= GAP[z]) {
    tone(BUZZ, 2000, 60);                  // short beep
    lastBeep = millis();
  }
  Serial.print("d = "); Serial.print(d, 1);
  Serial.print(" cm  zone "); Serial.println(z);
  delay(60);
}

d = 999.0 cm  zone 0
d = 150.8 cm  zone 0
d = 90.5 cm  zone 1
d = 40.2 cm  zone 2
d = 12.1 cm  zone 3

سيارة تقترب من الحائط، والسطر الأول بلا صدى. المسافة المعروضة أكبر قليلا من الحقيقية: 150.8 cm لجسم على بعد 150 cm ، لأن البرنامج يقسم على 58 بدل 58.31. حدود المناطق بزمن الصدى: t = 58·d ، أي 5800 ، 2900 و 1450 µs.

חיישן תנועה PIR – حسّاس الحركة بالأشعة تحت الحمراء HC-SR501 (PIR Motion Sensor)

في داخله عنصر كهروحراري (פירואלקטרי) له نصفان، وفوقه قبّة بيضاء هي عدسة فرينل (עדשת פרנל) تقسم مجال الرؤية إلى قطاعات. عندما يعبر إنسان من قطاع إلى قطاع يصل إلى النصفين إشعاع مختلف فيرتفع المخرج. لذلك الإنسان الجالس بلا حراك «يختفي» بعد قليل: الحسّاس يكشف التغيّر وليس الوجود.

على الوحدة أيضا جسر صغير لاختيار وضع إعادة القدح (מצב הפעלה חוזרת). في الوضع H تبدأ كل حركة جديدة زمن الإمساك من البداية، فيبقى المخرج مرتفعا ما دامت الحركة مستمرة. في الوضع L ينخفض المخرج بعد T_x حتى لو استمرت الحركة. القيم تختلف قليلا بين نُسخ الوحدة.

نريد أن يُضيء المصباح عند الحركة ويبقى مضاءً 30 s بعد آخر حركة. نضبط الوحدة على الوضع H وعلى أقصر T_x ، ونترك حساب المدّة للبرنامج: نحفظ في lastMotion وقت آخر قراءة HIGH ، ونطفئ عندما يمرّ 30 s منذ ذلك الوقت.

const int PIR = 2, LAMP = 7;
const unsigned long HOLD = 30000UL;        // ms after the last motion
unsigned long lastMotion = 0;
bool lampOn = false;
void report(const char *msg) {
  Serial.print("t = "); Serial.print(millis() / 1000.0, 1);
  Serial.print(" s  "); Serial.println(msg);
}
void setup() {
  Serial.begin(9600);
  pinMode(PIR, INPUT); pinMode(LAMP, OUTPUT);
  delay(60000UL);                          // PIR warm-up
  Serial.println("ready");
}
void loop() {
  unsigned long now = millis();
  if (digitalRead(PIR) == HIGH) {
    lastMotion = now;                      // motion: restart the timer
    if (!lampOn) {
      lampOn = true; digitalWrite(LAMP, HIGH); report("lamp ON");
    }
  }
  if (lampOn && now - lastMotion >= HOLD) {
    lampOn = false; digitalWrite(LAMP, LOW); report("lamp OFF");
  }
}

ready
t = 65.2 s  lamp ON
t = 114.7 s  lamp OFF
t = 152.3 s  lamp ON
t = 185.1 s  lamp OFF

חיישני מרחק ותנועה נוספים – حسّاسات أخرى للمسافة والحركة (Other Distance and Motion Sensors)

إلى جانب الحسّاس فوق الصوتي وحسّاس الحركة نلتقي في المشاريع بحسّاسات أخرى للمسافة والحركة. لا نتوسّع فيها في هذا الكتاب، لكن من المفيد أن نعرف ماذا يقيس كل منها، ما مداه، ما نوع مخرجه، وأين يُستعمل. الجدول يقارن بينها وبين الحسّاسين اللذين تعلّمناهما:

ملخّص قوانين الفصل:

قاموس المصطلحات – מילון מונחים:

أسئلة للتمرين: