قياس التيار والجهد والقدرة

מדידת מתח ישר גבוה מתחום הממיר – قياس جهد مستمر أعلى من مدى المحوّل (High DC Voltage)

المحوّل التماثلي-الرقمي في Uno يقبل جهدا من 0 حتى V_ref = 5 V فقط. أما الجهود التي نريد مراقبتها فأعلى: بطارية 12 V ، لوح شمسي، مصدر تغذية مختبري. الحلّ هو مُجزِّء جهد (מחלק מתח) من مقاومتين: يخفض الجهد بنسبة ثابتة قبل الطرف، ونضرب القراءة في البرنامج بنفس النسبة.

البرنامج يمرّ بخطوتين: يحوّل القيمة الخام N إلى الجهد على الطرف، كما في كل مدخل تماثلي، ثم يضرب الجهد في معامل التقسيم فيحصل على الجهد قبل المُجزِّء:

نستعمل قيم وحدة «حسّاس الجهد» الشائعة للمدى 0–25 V: R₁ = 30 kΩ و R₂ = 7.5 kΩ ، ونتحقّق منها في المثال بعد البرنامج. في الرسم أضفنا للحماية ديود زينر (דיודת זנר) ومكثّفا. إذا وُصل خطأً جهد أعلى من 25 V ، يمنع الزينر جهد الطرف من الارتفاع كثيرا فوق 5 V ، و R₁ الكبيرة تحدّ تياره. والمكثّف يخفّف التشويش فتثبت القراءة.

// DC voltmeter 0-25 V: divider 30k / 7.5k into A0
const int   PIN_V = A0;
const float R1    = 30000.0;
const float R2    = 7500.0;
const float VREF  = 5.0;

void setup() {
  Serial.begin(9600);
}

void loop() {
  long sum = 0;
  for (int i = 0; i < 16; i++) sum += analogRead(PIN_V);
  float n    = sum / 16.0;                 // averaged raw value
  float vPin = n * VREF / 1023.0;          // voltage on A0
  float vIn  = vPin * (R1 + R2) / R2;      // voltage before the divider
  Serial.print("N = ");        Serial.print(n, 1);
  Serial.print("  Vpin = ");   Serial.print(vPin, 3);
  Serial.print(" V  Vin = ");  Serial.print(vIn, 2);
  Serial.println(" V");
  delay(1000);
}

N = 204.0  Vpin = 0.997 V  Vin = 4.99 V
N = 491.0  Vpin = 2.400 V  Vin = 12.00 V
N = 757.0  Vpin = 3.700 V  Vin = 18.50 V
N = 982.0  Vpin = 4.800 V  Vin = 24.00 V

رفعنا جهد مصدر مختبري تدريجيا إلى 5 V ، 12 V ، 18.5 V ، 24 V. القراءة أقلّ قليلا من الجهد الحقيقي، لأن المحوّل يأخذ الجزء الصحيح فقط.

חיישן זרם ACS712 מבוסס אפקט הול – حسّاس التيار ACS712 بتأثير هول (Hall-Effect Current Sensor)

في الشريحة ACS712 يمرّ التيار المقيس في مسار نحاسي داخل الغلاف، بين الطرفين IP+ و IP−. التيار يولّد حول المسار مجالا مغناطيسيا، وعنصر هول قريب منه يحوّل المجال إلى جهد، ثم يضخّمه مضخّم داخلي إلى طرف المخرج OUT. بين المسار النحاسي ودائرة المخرج عزل جلفاني (בידוד גלווני): لا يوجد بينهما أيّ توصيل كهربائي، ولذلك لا تحتاج دائرة الحمل إلى أرضي مشترك مع المتحكّم. هذا حسّاس التيار (חיישן זרם) مخرجه تماثلي، ويقيس التيار في الاتجاهين.

التغذية 5 V ، والمخرج عند تيار صفر يساوي نصف التغذية V_CC2 = 2.5 V. الحساسية هي مقدار تغيّر المخرج لكل أمبير: في الطراز 5 A يرتفع المخرج 185 mV مع كل أمبير. الحساسية وجهد الصفر قيم نموذجية حسب ورقة البيانات. التيار في الاتجاه الموجب (من IP+ إلى IP−) يرفع المخرج فوق 2.5 V ، والتيار المعاكس يخفضه تحتها. في الطراز 5 A يتحرّك المخرج بين 1.575 V و 3.425 V.

في Uno تساوي وحدة واحدة من القيمة الخام نحو 4.9 mV ، وهي في الطراز 5 A نحو 26 mA. لذلك يأخذ البرنامج متوسّط عدّة قراءات. وجهد الصفر ليس 2.5 V بالضبط، بل يختلف قليلا من وحدة إلى أخرى. الحلّ البسيط: يقرأ البرنامج المخرج عند بدء التشغيل، والحمل مفصول، ويحفظه كجهد الصفر V₀.

// ACS712-05B: zero read at start-up, current in amps
const int   PIN_I = A0;
const float SENS  = 0.185;          // V per A (typical, 5 A part)
const float VPC   = 5.0 / 1023.0;   // volts per count

float zeroV = 0;                    // output at zero current

float readVolts() {
  long s = 0;
  for (int i = 0; i < 64; i++) s += analogRead(PIN_I);
  return s / 64.0 * VPC;
}

void setup() {
  Serial.begin(9600);
  zeroV = readVolts();              // load must be OFF here
  Serial.print("zero = "); Serial.print(zeroV, 3); Serial.println(" V");
}

void loop() {
  float v = readVolts();
  float amps = (v - zeroV) / SENS;
  Serial.print("Vout = "); Serial.print(v, 3);
  Serial.print(" V  I = "); Serial.print(amps, 2); Serial.println(" A");
  delay(500);
}

zero = 2.468 V
Vout = 2.468 V  I = 0.00 A
Vout = 2.688 V  I = 1.19 A
Vout = 2.913 V  I = 2.40 A
Vout = 2.243 V  I = -1.22 A

جهد الصفر لهذه الوحدة 2.47 V (وليس 2.5 V)، والتيار في الحمل أخذ القيم 0 A ، 1.2 A ، 2.4 A ، −1.2 A. القيمة الأخيرة سالبة لأننا عكسنا اتجاه التيار في الحمل.

طرق أخرى لقياس التيار – שיטות אחרות למדידת זרם:

إلى جانب ACS712 توجد طريقتان شائعتان: مقاومة قياس التيار (נגד מדידה (שנט))، وهي مقاومة صغيرة جدا على التوالي مع الحمل، ومحوّل التيار ذو القلب المنفصل (שנאי זרם מתפצל)، الذي ينفتح كالمِلقط ويُطبَق حول موصل. لا ندرسهما بالتفصيل في هذا الكتاب؛ الجدول يلخّص متى نستعمل كل طريقة.

חישוב הספק לעומס זרם ישר – حساب القدرة لحمل تيار مستمر (DC Power)

عندما يقيس المتحكّم الجهد على الحمل (البند 9.1) والتيار فيه (البند 9.2)، يحسب القدرة (הספק) بعملية ضرب واحدة. هكذا يعرف مثلا كم قدرة يأخذ محرّك، ويلاحظ متى يعمل الحمل بقدرة أكبر من العادة.

ملخّص قوانين الفصل:

قاموس المصطلحات – מילון מונחים:

أسئلة للتمرين: